<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># $Id: Tree.pm,v 1.2 2003-07-31 07:54:51 matt Exp $

package XML::Parser::Style::Tree;
$XML::Parser::Built_In_Styles{Tree} = 1;

sub Init {
  my $expat = shift;
  $expat-&gt;{Lists} = [];
  $expat-&gt;{Curlist} = $expat-&gt;{Tree} = [];
}

sub Start {
  my $expat = shift;
  my $tag = shift;
  my $newlist = [ { @_ } ];
  push @{ $expat-&gt;{Lists} }, $expat-&gt;{Curlist};
  push @{ $expat-&gt;{Curlist} }, $tag =&gt; $newlist;
  $expat-&gt;{Curlist} = $newlist;
}

sub End {
  my $expat = shift;
  my $tag = shift;
  $expat-&gt;{Curlist} = pop @{ $expat-&gt;{Lists} };
}

sub Char {
  my $expat = shift;
  my $text = shift;
  my $clist = $expat-&gt;{Curlist};
  my $pos = $#$clist;
  
  if ($pos &gt; 0 and $clist-&gt;[$pos - 1] eq '0') {
    $clist-&gt;[$pos] .= $text;
  } else {
    push @$clist, 0 =&gt; $text;
  }
}

sub Final {
  my $expat = shift;
  delete $expat-&gt;{Curlist};
  delete $expat-&gt;{Lists};
  $expat-&gt;{Tree};
}

1;
__END__

=head1 NAME

XML::Parser::Style::Tree - Tree style parser

=head1 SYNOPSIS

  use XML::Parser;
  my $p = XML::Parser-&gt;new(Style =&gt; 'Tree');
  my $tree = $p-&gt;parsefile('foo.xml');

=head1 DESCRIPTION

This module implements XML::Parser's Tree style parser.

When parsing a document, C&lt;parse()&gt; will return a parse tree for the
document. Each node in the tree
takes the form of a tag, content pair. Text nodes are represented with
a pseudo-tag of "0" and the string that is their content. For elements,
the content is an array reference. The first item in the array is a
(possibly empty) hash reference containing attributes. The remainder of
the array is a sequence of tag-content pairs representing the content
of the element.

So for example the result of parsing:

  &lt;foo&gt;&lt;head id="a"&gt;Hello &lt;em&gt;there&lt;/em&gt;&lt;/head&gt;&lt;bar&gt;Howdy&lt;ref/&gt;&lt;/bar&gt;do&lt;/foo&gt;

would be:
             Tag   Content
  ==================================================================
  [foo, [{}, head, [{id =&gt; "a"}, 0, "Hello ",  em, [{}, 0, "there"]],
              bar, [         {}, 0, "Howdy",  ref, [{}]],
                0, "do"
        ]
  ]

The root document "foo", has 3 children: a "head" element, a "bar"
element and the text "do". After the empty attribute hash, these are
represented in it's contents by 3 tag-content pairs.

=cut
</pre></body></html>