<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package autodie::hints;

use strict;
use warnings;

use constant PERL58 =&gt; ( $] &lt; 5.009 );

our $VERSION = '2.29001';

# ABSTRACT: Provide hints about user subroutines to autodie

=head1 NAME

autodie::hints - Provide hints about user subroutines to autodie

=head1 SYNOPSIS

    package Your::Module;

    our %DOES = ( 'autodie::hints::provider' =&gt; 1 );

    sub AUTODIE_HINTS {
        return {
            foo =&gt; { scalar =&gt; HINTS, list =&gt; SOME_HINTS },
            bar =&gt; { scalar =&gt; HINTS, list =&gt; MORE_HINTS },
        }
    }

    # Later, in your main program...

    use Your::Module qw(foo bar);
    use autodie      qw(:default foo bar);

    foo();         # succeeds or dies based on scalar hints

    # Alternatively, hints can be set on subroutines we've
    # imported.

    use autodie::hints;
    use Some::Module qw(think_positive);

    BEGIN {
        autodie::hints-&gt;set_hints_for(
            \&amp;think_positive,
            {
                fail =&gt; sub { $_[0] &lt;= 0 }
            }
        )
    }
    use autodie qw(think_positive);

    think_positive(...);    # Returns positive or dies.


=head1 DESCRIPTION

=head2 Introduction

The L&lt;autodie&gt; pragma is very smart when it comes to working with
Perl's built-in functions.  The behaviour for these functions are
fixed, and C&lt;autodie&gt; knows exactly how they try to signal failure.

But what about user-defined subroutines from modules?  If you use
C&lt;autodie&gt; on a user-defined subroutine then it assumes the following
behaviour to demonstrate failure:

=over

=item *

A false value, in scalar context

=item * 

An empty list, in list context

=item *

A list containing a single undef, in list context

=back

All other return values (including the list of the single zero, and the
list containing a single empty string) are considered successful.  However,
real-world code isn't always that easy.  Perhaps the code you're working
with returns a string containing the word "FAIL" upon failure, or a
two element list containing C&lt;(undef, "human error message")&gt;.  To make
autodie work with these sorts of subroutines, we have
the I&lt;hinting interface&gt;.

The hinting interface allows I&lt;hints&gt; to be provided to C&lt;autodie&gt;
on how it should detect failure from user-defined subroutines.  While
these I&lt;can&gt; be provided by the end-user of C&lt;autodie&gt;, they are ideally
written into the module itself, or into a helper module or sub-class
of C&lt;autodie&gt; itself.

=head2 What are hints?

A I&lt;hint&gt; is a subroutine or value that is checked against the
return value of an autodying subroutine.  If the match returns true,
C&lt;autodie&gt; considers the subroutine to have failed.

If the hint provided is a subroutine, then C&lt;autodie&gt; will pass
the complete return value to that subroutine.  If the hint is
any other value, then C&lt;autodie&gt; will smart-match against the
value provided.  In Perl 5.8.x there is no smart-match operator, and as such
only subroutine hints are supported in these versions.

Hints can be provided for both scalar and list contexts.  Note
that an autodying subroutine will never see a void context, as
C&lt;autodie&gt; always needs to capture the return value for examination.
Autodying subroutines called in void context act as if they're called
in a scalar context, but their return value is discarded after it
has been checked.

=head2 Example hints

Hints may consist of subroutine references, objects overloading
smart-match, regular expressions, and depending on Perl version possibly
other things.  You can specify different hints for how
failure should be identified in scalar and list contexts.

These examples apply for use in the C&lt;AUTODIE_HINTS&gt; subroutine and when
calling C&lt;autodie::hints-&gt;set_hints_for()&gt;.

The most common context-specific hints are:

        # Scalar failures always return undef:
            {  scalar =&gt; sub { !defined($_[0]) }  }

        # Scalar failures return any false value [default expectation]:
            {  scalar =&gt; sub { ! $_[0] }  }

        # Scalar failures always return zero explicitly:
            {  scalar =&gt; sub { defined($_[0]) &amp;&amp; $_[0] eq '0' }  }

        # List failures always return an empty list:
            {  list =&gt; sub { !@_ }  }

        # List failures return () or (undef) [default expectation]:
            {  list =&gt; sub { ! @_ || @_ == 1 &amp;&amp; !defined $_[0] }  }

        # List failures return () or a single false value:
            {  list =&gt; sub { ! @_ || @_ == 1 &amp;&amp; !$_[0] }  }

        # List failures return (undef, "some string")
            {  list =&gt; sub { @_ == 2 &amp;&amp; !defined $_[0] }  }

        # Unsuccessful foo() returns 'FAIL' or '_FAIL' in scalar context,
        #                    returns (-1) in list context...
        autodie::hints-&gt;set_hints_for(
            \&amp;foo,
            {
                scalar =&gt; qr/^ _? FAIL $/xms,
                list   =&gt; sub { @_ == 1 &amp;&amp; $_[0] eq -1 },
            }
        );

        # Unsuccessful foo() returns 0 in all contexts...
        autodie::hints-&gt;set_hints_for(
            \&amp;foo,
            {
                scalar =&gt; sub { defined($_[0]) &amp;&amp; $_[0] == 0 },
                list   =&gt; sub { @_ == 1 &amp;&amp; defined($_[0]) &amp;&amp; $_[0] == 0 },
            }
        );

This "in all contexts" construction is very common, and can be
abbreviated, using the 'fail' key.  This sets both the C&lt;scalar&gt;
and C&lt;list&gt; hints to the same value:

        # Unsuccessful foo() returns 0 in all contexts...
        autodie::hints-&gt;set_hints_for(
            \&amp;foo,
            {
                fail =&gt; sub { @_ == 1 and defined $_[0] and $_[0] == 0 }
            }
	);

        # Unsuccessful think_positive() returns negative number on failure...
        autodie::hints-&gt;set_hints_for(
            \&amp;think_positive,
            {
                fail =&gt; sub { $_[0] &lt; 0 }
            }
	);

        # Unsuccessful my_system() returns non-zero on failure...
        autodie::hints-&gt;set_hints_for(
            \&amp;my_system,
            {
                fail =&gt; sub { $_[0] != 0 }
            }
	);

=head1 Manually setting hints from within your program

If you are using a module which returns something special on failure, then
you can manually create hints for each of the desired subroutines.  Once
the hints are specified, they are available for all files and modules loaded
thereafter, thus you can move this work into a module and it will still
work.

	use Some::Module qw(foo bar);
	use autodie::hints;

	autodie::hints-&gt;set_hints_for(
		\&amp;foo,
		{
			scalar =&gt; SCALAR_HINT,
			list   =&gt; LIST_HINT,
		}
	);
	autodie::hints-&gt;set_hints_for(
		\&amp;bar,
                { fail =&gt; SOME_HINT, }
	);

It is possible to pass either a subroutine reference (recommended) or a fully
qualified subroutine name as the first argument.  This means you can set hints
on modules that I&lt;might&gt; get loaded:

	use autodie::hints;
	autodie::hints-&gt;set_hints_for(
		'Some::Module:bar', { fail =&gt; SCALAR_HINT, }
	);

This technique is most useful when you have a project that uses a
lot of third-party modules.  You can define all your possible hints
in one-place.  This can even be in a sub-class of autodie.  For
example:

        package my::autodie;

        use parent qw(autodie);
        use autodie::hints;

        autodie::hints-&gt;set_hints_for(...);

        1;

You can now C&lt;use my::autodie&gt;, which will work just like the standard
C&lt;autodie&gt;, but is now aware of any hints that you've set.

=head1 Adding hints to your module

C&lt;autodie&gt; provides a passive interface to allow you to declare hints for
your module.  These hints will be found and used by C&lt;autodie&gt; if it
is loaded, but otherwise have no effect (or dependencies) without autodie.
To set these, your module needs to declare that it I&lt;does&gt; the
C&lt;autodie::hints::provider&gt; role.  This can be done by writing your
own C&lt;DOES&gt; method, using a system such as C&lt;Class::DOES&gt; to handle
the heavy-lifting for you, or declaring a C&lt;%DOES&gt; package variable
with a C&lt;autodie::hints::provider&gt; key and a corresponding true value.

Note that checking for a C&lt;%DOES&gt; hash is an C&lt;autodie&gt;-only
short-cut.  Other modules do not use this mechanism for checking
roles, although you can use the C&lt;Class::DOES&gt; module from the
CPAN to allow it.

In addition, you must define a C&lt;AUTODIE_HINTS&gt; subroutine that returns
a hash-reference containing the hints for your subroutines:

        package Your::Module;

        # We can use the Class::DOES from the CPAN to declare adherence
        # to a role.

        use Class::DOES 'autodie::hints::provider' =&gt; 1;

        # Alternatively, we can declare the role in %DOES.  Note that
        # this is an autodie specific optimisation, although Class::DOES
        # can be used to promote this to a true role declaration.

        our %DOES = ( 'autodie::hints::provider' =&gt; 1 );

        # Finally, we must define the hints themselves.

	sub AUTODIE_HINTS {
	    return {
	        foo =&gt; { scalar =&gt; HINTS, list =&gt; SOME_HINTS },
	        bar =&gt; { scalar =&gt; HINTS, list =&gt; MORE_HINTS },
	        baz =&gt; { fail =&gt; HINTS },
	    }
	}

This allows your code to set hints without relying on C&lt;autodie&gt; and
C&lt;autodie::hints&gt; being loaded, or even installed.  In this way your
code can do the right thing when C&lt;autodie&gt; is installed, but does not
need to depend upon it to function.

=head1 Insisting on hints

When a user-defined subroutine is wrapped by C&lt;autodie&gt;, it will
use hints if they are available, and otherwise reverts to the
I&lt;default behaviour&gt; described in the introduction of this document.
This can be problematic if we expect a hint to exist, but (for
whatever reason) it has not been loaded.

We can ask autodie to I&lt;insist&gt; that a hint be used by prefixing
an exclamation mark to the start of the subroutine name.  A lone
exclamation mark indicates that I&lt;all&gt; subroutines after it must
have hints declared.

	# foo() and bar() must have their hints defined
	use autodie qw( !foo !bar baz );

	# Everything must have hints (recommended).
	use autodie qw( ! foo bar baz );

	# bar() and baz() must have their hints defined
	use autodie qw( foo ! bar baz );

        # Enable autodie for all of Perl's supported built-ins,
        # as well as for foo(), bar() and baz().  Everything must
        # have hints.
        use autodie qw( ! :all foo bar baz );

If hints are not available for the specified subroutines, this will cause a
compile-time error.  Insisting on hints for Perl's built-in functions
(eg, C&lt;open&gt; and C&lt;close&gt;) is always successful.

Insisting on hints is I&lt;strongly&gt; recommended.

=cut

# TODO: implement regular expression hints

use constant UNDEF_ONLY       =&gt; sub { not defined $_[0] };
use constant EMPTY_OR_UNDEF   =&gt; sub {
    ! @_ or
    @_==1 &amp;&amp; !defined $_[0]
};

use constant EMPTY_ONLY     =&gt; sub { @_ == 0 };
use constant EMPTY_OR_FALSE =&gt; sub {
    ! @_ or
    @_==1 &amp;&amp; !$_[0]
};

use constant SINGLE_TRUE =&gt; sub { @_ == 1 and not $_[0] };

use constant DEFAULT_HINTS =&gt; {
    scalar =&gt; UNDEF_ONLY,
    list   =&gt; EMPTY_OR_UNDEF,
};


use constant HINTS_PROVIDER =&gt; 'autodie::hints::provider';

our $DEBUG = 0;

# Only ( undef ) is a strange but possible situation for very
# badly written code.  It's not supported yet.

my %Hints = (
    'File::Copy::copy' =&gt; { scalar =&gt; SINGLE_TRUE, list =&gt; SINGLE_TRUE },
    'File::Copy::move' =&gt; { scalar =&gt; SINGLE_TRUE, list =&gt; SINGLE_TRUE },
    'File::Copy::cp'   =&gt; { scalar =&gt; SINGLE_TRUE, list =&gt; SINGLE_TRUE },
    'File::Copy::mv'   =&gt; { scalar =&gt; SINGLE_TRUE, list =&gt; SINGLE_TRUE },
);

# Start by using Sub::Identify if it exists on this system.

eval { require Sub::Identify; Sub::Identify-&gt;import('get_code_info'); };

# If it doesn't exist, we'll define our own.  This code is directly
# taken from Rafael Garcia's Sub::Identify 0.04, used under the same
# license as Perl itself.

if ($@) {
    require B;

    no warnings 'once';

    *get_code_info = sub ($) {

        my ($coderef) = @_;
        ref $coderef or return;
        my $cv = B::svref_2object($coderef);
        $cv-&gt;isa('B::CV') or return;
        # bail out if GV is undefined
        $cv-&gt;GV-&gt;isa('B::SPECIAL') and return;

        return ($cv-&gt;GV-&gt;STASH-&gt;NAME, $cv-&gt;GV-&gt;NAME);
    };

}

sub sub_fullname {
    return join( '::', get_code_info( $_[1] ) );
}

my %Hints_loaded = ();

sub load_hints {
    my ($class, $sub) = @_;

    my ($package) = ( $sub =~ /(.*)::/ );

    if (not defined $package) {
        require Carp;
        Carp::croak(
            "Internal error in autodie::hints::load_hints - no package found.
        ");
    }

    # Do nothing if we've already tried to load hints for
    # this package.
    return if $Hints_loaded{$package}++;

    my $hints_available = 0;

    {
        no strict 'refs';   ## no critic

        if ($package-&gt;can('DOES') and $package-&gt;DOES(HINTS_PROVIDER) ) {
            $hints_available = 1;
        }
        elsif ( PERL58 and $package-&gt;isa(HINTS_PROVIDER) ) {
            $hints_available = 1;
        }
        elsif ( ${"${package}::DOES"}{HINTS_PROVIDER.""} ) {
            $hints_available = 1;
        }
    }

    return if not $hints_available;

    my %package_hints = %{ $package-&gt;AUTODIE_HINTS };

    foreach my $sub (keys %package_hints) {

        my $hint = $package_hints{$sub};

        # Ensure we have a package name.
        $sub = "${package}::$sub" if $sub !~ /::/;

        # TODO - Currently we don't check for conflicts, should we?
        $Hints{$sub} = $hint;

        $class-&gt;normalise_hints(\%Hints, $sub);
    }

    return;

}

sub normalise_hints {
    my ($class, $hints, $sub) = @_;

    if ( exists $hints-&gt;{$sub}-&gt;{fail} ) {

        if ( exists $hints-&gt;{$sub}-&gt;{scalar} or
             exists $hints-&gt;{$sub}-&gt;{list}
        ) {
            # TODO: Turn into a proper diagnostic.
            require Carp;
            local $Carp::CarpLevel = 1;
            Carp::croak("fail hints cannot be provided with either scalar or list hints for $sub");
        }

        # Set our scalar and list hints.

        $hints-&gt;{$sub}-&gt;{scalar} = 
        $hints-&gt;{$sub}-&gt;{list} = delete $hints-&gt;{$sub}-&gt;{fail};

        return;

    }

    # Check to make sure all our hints exist.

    foreach my $hint (qw(scalar list)) {
        if ( not exists $hints-&gt;{$sub}-&gt;{$hint} ) {
            # TODO: Turn into a proper diagnostic.
            require Carp;
            local $Carp::CarpLevel = 1;
            Carp::croak("$hint hint missing for $sub");
        }
    }

    return;
}

sub get_hints_for {
    my ($class, $sub) = @_;

    my $subname = $class-&gt;sub_fullname( $sub );

    # If we have hints loaded for a sub, then return them.

    if ( exists $Hints{ $subname } ) {
        return $Hints{ $subname };
    }

    # If not, we try to load them...

    $class-&gt;load_hints( $subname );

    # ...and try again!

    if ( exists $Hints{ $subname } ) {
        return $Hints{ $subname };
    }

    # It's the caller's responsibility to use defaults if desired.
    # This allows on autodie to insist on hints if needed.

    return;

}

sub set_hints_for {
    my ($class, $sub, $hints) = @_;

    if (ref $sub) {
        $sub = $class-&gt;sub_fullname( $sub );

        require Carp;

        $sub or Carp::croak("Attempts to set_hints_for unidentifiable subroutine");
    }

    if ($DEBUG) {
        warn "autodie::hints: Setting $sub to hints: $hints\n";
    }

    $Hints{ $sub } = $hints;

    $class-&gt;normalise_hints(\%Hints, $sub);

    return;
}

1;

__END__


=head1 Diagnostics

=over 4

=item Attempts to set_hints_for unidentifiable subroutine

You've called C&lt;&lt; autodie::hints-&gt;set_hints_for() &gt;&gt; using a subroutine
reference, but that reference could not be resolved back to a
subroutine name.  It may be an anonymous subroutine (which can't
be made autodying), or may lack a name for other reasons.

If you receive this error with a subroutine that has a real name,
then you may have found a bug in autodie.  See L&lt;autodie/BUGS&gt;
for how to report this.

=item fail hints cannot be provided with either scalar or list hints for %s

When defining hints, you can either supply both C&lt;list&gt; and
C&lt;scalar&gt; keywords, I&lt;or&gt; you can provide a single C&lt;fail&gt; keyword.
You can't mix and match them.

=item %s hint missing for %s

You've provided either a C&lt;scalar&gt; hint without supplying
a C&lt;list&gt; hint, or vice-versa.  You I&lt;must&gt; supply both C&lt;scalar&gt;
and C&lt;list&gt; hints, I&lt;or&gt; a single C&lt;fail&gt; hint.

=back

=head1 ACKNOWLEDGEMENTS

=over 

=item *

Dr Damian Conway for suggesting the hinting interface and providing the
example usage.

=item *

Jacinta Richardson for translating much of my ideas into this
documentation.

=back

=head1 AUTHOR

Copyright 2009, Paul Fenwick E&lt;lt&gt;pjf@perltraining.com.auE&lt;gt&gt;

=head1 LICENSE

This module is free software.  You may distribute it under the
same terms as Perl itself.

=head1 SEE ALSO

L&lt;autodie&gt;, L&lt;Class::DOES&gt;

=for Pod::Coverage get_hints_for load_hints normalise_hints sub_fullname get_code_info

=cut
</pre></body></html>